Интерфейс хф + исходники 0.638

Monokini2 · 9 Ноя 2022

текст это и есть текстуры)

BIT_hack · 9 Ноя 2022

Monokini2 написал(а):
текст это и есть текстуры)

Ты просто текст урона без преобразование пихаешь в targetEmitter.Emitters[0].Texture=

Monokini2 · 9 Ноя 2022

За месяц уже забыл просто, по хорошему тоже доделать и выложить надо. Там эффект в эффекте, в первый передаем длину и текстуры, и в нем уже спавним отдельные эффекты с числами и крепим друг к дружке вроде

BIT_hack · 9 Ноя 2022

Monokini2 написал(а):
За месяц уже забыл просто, по хорошему тоже доделать и выложить надо. Там эффект в эффекте, в первый передаем длину и текстуры, и в нем уже спавним отдельные эффекты с числами и крепим друг к дружке вроде

Ок спасибо попробую разобраться!

BIT_hack · 9 Ноя 2022

Monokini2 написал(а):
!

Вот исправил код может пригодится тебе, а может еще кому)

Скрипт загрузчики эффекта (нужно подключить этот скрипт к вашему окну xdat)

C++:

/******************************************

    Разработчик: BITHACK

    Copyright (c) 1995,2022 Ваша компания

    Описание скрипта:....

 *******************************************/
class BIT_LoadTargetEffect extends UICommonAPI;

    #exec Texture Import File=Textures/Target.dds Name=Target Mips=Off MASKED=1

  var Emitter MyEmitter;

function OnRegisterEvent(){ /* Регистрация игровых событий */

    RegisterEvent( EV_TargetUpdate );
  }

function OnEvent(int Event_ID, string param) { /* Обработчик игровых событий */

   if ( Event_ID == EV_TargetUpdate)
    SpawnTargetEffect();
  }

function SpawnTargetEffect()
{
     local UserInfo info;
     local Actor MyActor;

   if(MyEmitter != None) {
    MyEmitter.NDestroy();
    MyEmitter = None;
  }
    MyActor = class'UIDATA_TARGET'.static.GetTargetActor();
    GetUserInfo(class'UIDATA_TARGET'.static.GetTargetID(), info);

    MyEmitter = Pawn(MyActor).Spawn(class'BIT_TargetEffect', Pawn(MyActor), , info.Loc, rot(0,0,0));
    MyEmitter.SetBase(Pawn(MyActor));
    MyEmitter.Emitters[0].Disabled = true;
    MyEmitter.Emitters[0].Texture = Texture'Target';//Текстру также можно взять из своего пака UTX
  }

    defaultproperties{}

Настройки эффекта

C++:

/******************************************

    Разработчик: BITHACK

    Copyright (c) 1995,2022 Ваша компания

    Описание скрипта:....

 *******************************************/
class BIT_TargetEffect extends Emitter;
  var Texture ProjectorTexture;
  var DynamicProjector TestDynamicProjector;

function PostBeginPlay(){
    Super.PostNetBeginPlay();
    TestDynamicProjector = Spawn(class'DynamicProjector', Instigator, , , Rotation);
    TestDynamicProjector.FrameBufferBlendingOp = PB_AlphaBlend;
    TestDynamicProjector.MaterialBlendingOp = PB_None;
    TestDynamicProjector.SetDrawScale(Emitters[0].StartLocationOffset.Z/600);
    TestDynamicProjector.bDynamicAttach = true;
    TestDynamicProjector.bClipBSP = true;
    TestDynamicProjector.bClipStaticMesh = true;
    TestDynamicProjector.bProjectTerrain = true;
    TestDynamicProjector.bProjectActor = true;
    TestDynamicProjector.bProjectBSP = true;
    TestDynamicProjector.bProjectOnUnlit = true;
    TestDynamicProjector.bLevelStatic = true;
    TestDynamicProjector.FOV = 1;
    TestDynamicProjector.MaxTraceDistance = 1000;
    TestDynamicProjector.bGradient = false;
    TestDynamicProjector.bSunAffect = false;
    SetTimer(0.05, false);
  }

function Tick(float deltatime){
     local rotator projectorRotation;

    projectorRotation.Pitch = -16400;
    projectorRotation.roll = 0;
    projectorRotation.Yaw = TestDynamicProjector.Rotation.Yaw + 50;
    super.Tick(deltatime);
    TestDynamicProjector.DetachProjector();
    TestDynamicProjector.SetLocation(Instigator.Location);
    TestDynamicProjector.SetRotation(projectorRotation);
    TestDynamicProjector.AttachProjector();
  }

function Timer(){
   if (TestDynamicProjector.ProjTexture.Name == 'None')
{
    Emitters[0].Texture.UClampMode = TC_Clamp;
    Emitters[0].Texture.VClampMode = TC_Clamp;
    Emitters[0].Texture.bAlphaTexture = true;
    TestDynamicProjector.ProjTexture = Emitters[0].Texture;
  }
  }

event Destroyed(){
    Level.ObjectPool.FreeObject(TestDynamicProjector.ProjTexture);
    TestDynamicProjector.ProjTexture = None;
    TestDynamicProjector.NDestroy();
    Super.Destroyed();
  }

defaultproperties{
    Begin Object class=SpriteEmitter name=SpriteEmitter0
    StartLocationOffset = (X=0,Y=0,Z=70)
    Name="SpriteEmitter0"
    End Object
    Emitters(0)=SpriteEmitter0
    bLightChanged=true
    bNoDelete=false
    bSunAffect=true

  }

Также можете скачать папку с исходниками!

Monokini2 написал(а):
Код:

targetEmitter.Emitters[0].StartLocationOffset.Z = P.DamageEffectOffset;

тут я передавал параметр для скалирования размера, но как оказалосьP.DamageEffectOffset везде одинаковый лучше плясать от P.CollisionRadius

Если я правильно тебя понял, тебе не удалось управлять размером картинки из своего скрипта? Если да то сделай так:

C++:

из функции function PostBeginPlay()   
Перенеси TestDynamicProjector.SetDrawScale(Emitters[0].StartLocationOffset.Z/600); 
В функцию function Tick(float deltatime)
    
После можешь управлять размером картинки из своей функции
targetEmitter..Emitters[0].StartLocationOffset.Z = 500;

Monokini2 · 10 Ноя 2022

BIT_hack, Да нет, с этим все ок, просто тогда я искал от чего скалировать размер текстуры выбрал сам параметр DamageEffectOffset а как оказалось он бесполезный и всегда равен 0)

BIT_hack · 10 Ноя 2022

Все больше не буду мучать твой код)) Почистил и добавил авто размер картинки по размеру моба)

Скрипт который нужно подключить к вашему окну xdat

C++:

/******************************************

    Разработчик: BITHACK

    Copyright (c) 1995,2022 Ваша компания

    Описание скрипта:....

 *******************************************/
class BIT_LoadTargetEffect extends UICommonAPI;

    #exec Texture Import File=Textures/Target.dds Name=Target Mips=Off MASKED=1

  var Emitter MyEmitter;

function OnRegisterEvent(){ /* Регистрация игровых событий */
    RegisterEvent( EV_TargetUpdate );
  }

function OnEvent(int Event_ID, string param) { /* Обработчик игровых событий */
   if ( Event_ID == EV_TargetUpdate)
    SpawnTargetEffect();
  }

function SpawnTargetEffect(){
     local UserInfo info;
     local Actor MyActor;

   if(MyEmitter != None) {
    MyEmitter.NDestroy();
    MyEmitter = None;
  }
    MyActor = class'UIDATA_TARGET'.static.GetTargetActor();
    GetUserInfo(class'UIDATA_TARGET'.static.GetTargetID(), info);
    MyEmitter = Pawn(MyActor).Spawn(class'BIT_TargetEffect', Pawn(MyActor), , info.Loc, rot(0,0,0));
    MyEmitter.SetBase(Pawn(MyActor));
    MyEmitter.Emitters[0].Disabled = true;
    MyEmitter.Emitters[0].StartLocationOffset.Z = Pawn(MyActor).CollisionRadius*10; //Задается размер картинки CollisionRadius*10
    MyEmitter.Emitters[0].Texture = Texture'Target'; //Текстру можно взять и из своего UTX
  }

    defaultproperties{}

Вспомогательный скрипт с настройками:

C++:

/******************************************

    Разработчик: BITHACK

    Copyright (c) 1995,2022 Ваша компания

    Описание скрипта:....

 *******************************************/
class BIT_TargetEffect extends Emitter;
  var Texture ProjectorTexture;
  var DynamicProjector TestDynamicProjector;

function PostBeginPlay(){
    Super.PostNetBeginPlay();
    TestDynamicProjector = Spawn(class'DynamicProjector', , , , Rotation);
    TestDynamicProjector.FrameBufferBlendingOp = PB_AlphaBlend;
    TestDynamicProjector.MaterialBlendingOp = PB_None;
    TestDynamicProjector.FOV = 1;
    SetTimer(0.05, false);
  }

function Tick(float deltatime){
     local rotator projectorRotation;
    TestDynamicProjector.SetDrawScale(Emitters[0].StartLocationOffset.Z/600);
    projectorRotation.Pitch = -16400;
    projectorRotation.roll = 0;
    projectorRotation.Yaw = TestDynamicProjector.Rotation.Yaw + 50;
    super.Tick(deltatime);
    TestDynamicProjector.DetachProjector();
    TestDynamicProjector.SetLocation(Location);
    TestDynamicProjector.SetRotation(projectorRotation);
    TestDynamicProjector.AttachProjector();
  }

function Timer(){
   if (TestDynamicProjector.ProjTexture.Name == 'None'){
    Emitters[0].Texture.UClampMode = TC_Clamp;
    Emitters[0].Texture.VClampMode = TC_Clamp;
    Emitters[0].Texture.bAlphaTexture = true;
    TestDynamicProjector.ProjTexture = Emitters[0].Texture;
  }
  }

event Destroyed(){
    Level.ObjectPool.FreeObject(TestDynamicProjector.ProjTexture);
    TestDynamicProjector.ProjTexture = None;
    TestDynamicProjector.NDestroy();
    Super.Destroyed();
  }

    defaultproperties{
    Begin Object class=SpriteEmitter name=SpriteEmitter0
    StartLocationOffset = (X=0,Y=0,Z=70)
    Name="SpriteEmitter0"
    End Object
    Emitters(0)=SpriteEmitter0
    bLightChanged=true
    bNoDelete=false
  }

Также прикрепил исходники

Monokini2 · 10 Ноя 2022

там еще насколько помню Event_ID == EV_TargetUpdate срабатывает не только когда ты новый таргет берешь, но и другие игроки)

BIT_hack · 10 Ноя 2022

Monokini2 написал(а):
там еще насколько помню Event_ID == EV_TargetUpdate срабатывает не только когда ты новый таргет берешь, но и другие игроки)

Ок поменял на RegisterEvent( EV_ReceiveTargetLevelDiff ); теперь только свой таргет походу за это отвечает

Monokini2 · 10 Ноя 2022

Ну так покекать, дамаг на эффекте)
спавнит на павне в таргете весь исходящий дамаг из EV_SystemMessage, но вроде можно прикрутить с сервера
Из минусов - дамаг на эффектах с текстурой , 9 знаков, при быстрых зумах проблема с высотой, при сильном отдалении скрывается движковым туманом? (disablefogging что-то неработает), ну и модификаторы скалирования и отступов текстур подбирал на глазок, надо геометрию почитать)).
Вообще еще хочется попробовать спроецировать эффект на сферу вокруг playercontrollera и уже ее вращать, по идее решит проблему с высотой и видимостью на расстоянии, но надо додумать

default_npc · 10 Ноя 2022

Monokini2 написал(а):
Ну так покекать, дамаг на эффекте)
спавнит на павне в таргете весь исходящий дамаг из EV_SystemMessage, но вроде можно прикрутить с сервера
Из минусов - дамаг на эффектах с текстурой , 9 знаков, при быстрых зумах проблема с высотой, при сильном отдалении скрывается движковым туманом? (disablefogging что-то неработает), ну и модификаторы скалирования и отступов текстур подбирал на глазок, надо геометрию почитать)).
Вообще еще хочется попробовать спроецировать эффект на сферу вокруг playercontrollera и уже ее вращать, по идее решит проблему с высотой и видимостью на расстоянии, но надо додумать

а что произойдёт, если ударить 50 нпц одновременно?

Monokini2 · 10 Ноя 2022

так я там чет перемудрил когда удалял из черновика, щас посмотрю почему не спавнит интерфейсом
но сам эффект был рабочий)

default_npc написал(а):
а что произойдёт, если ударить 50 нпц одновременно?

Это точно к Rolo, он там на пике x10 эффекты на каждый удар спавнил для теста)

BIT_hack · 10 Ноя 2022

Monokini2 написал(а):
Ну так покекать, дамаг на эффекте)
спавнит на павне в таргете весь исходящий дамаг из EV_SystemMessage, но вроде можно прикрутить с сервера
Из минусов - дамаг на эффектах с текстурой , 9 знаков, при быстрых зумах проблема с высотой, при сильном отдалении скрывается движковым туманом? (disablefogging что-то неработает), ну и модификаторы скалирования и отступов текстур подбирал на глазок, надо геометрию почитать)).
Вообще еще хочется попробовать спроецировать эффект на сферу вокруг playercontrollera и уже ее вращать, по идее решит проблему с высотой и видимостью на расстоянии, но надо додумать

О спасибо! Интересно буду разбираться)!

Monokini2 · 10 Ноя 2022

Вообщем загрузка массива текстур в тестовом классе в OnLoad почему то фейлится, а в черновом в OnLoad все норм грузится без понятия почему

если переставить в функцию спавна то покажет урон

C++:

    for (idx=0; idx<10; idx++)
    {
        DamageTextures[idx] = Texture(DynamicLoadObject("MonIca_DamageEffect_Tex.0"$idx, class'Texture'));
    }
    DamageTextures[10] = Texture(DynamicLoadObject("MonIca_DamageEffect_Tex.blocked", class'Texture'));
    DamageTextures[11] = Texture(DynamicLoadObject("MonIca_DamageEffect_Tex.evaded", class'Texture'));
    DamageTextures[12] = Texture(DynamicLoadObject("MonIca_DamageEffect_Tex.resisted", class'Texture'));

update: вообщем судя по всему массив у меня не заполнялся потому что я в xdat тестовому окну размеры любые не проставил

Spectre · 19 Ноя 2022

Sup is it possible you guys drop here the .uc files from MonIca_DamageEffect.u?

Monokini2 · 20 Ноя 2022

Spectre, you don't need it)

Monokini2 · 20 Ноя 2022

Может кто-нибудь подсказать где найти этих ребят в большем разрешении? Вроде все utx просмотрел

BIT_hack · 20 Ноя 2022

Monokini2 написал(а):
Может кто-нибудь подсказать где найти этих ребят в большем разрешении? Вроде все utx просмотрел

Посмотреть вложение 46398

"SysTextures\ui2.ugx" open with the program l2Tool Java 8.20

Monokini2 · 20 Ноя 2022

BIT_hack, да эти я нашел, думал большие где есть

default_npc · 20 Ноя 2022

Monokini2 написал(а):
BIT_hack, да эти я нашел, думал большие где есть

Если нужно в игре как элемент интерфейса - сильвупле изучать split9 у текстур или на худой конец uv внутри элемента.

Если нужно куда то ещё - то есть фотошоп, при использовании которого - эту условную 64х64 можно успешно раскукожить до ~256x256 (не без мучений с ручной правкой, конечно же, ибо как пить дать уплывут как минимум цвета).

//Можно ещё попробовать воспользоваться нейросетевыми онлайн раскукоживателями - они тоже вроде имеют смысл, с относительно статичными картинками, без большого числа деталей.

Интерфейс хф + исходники 0.638

Постоялец

Знающий

Постоялец

Знающий

Знающий

Вложения

Постоялец

Знающий

Вложения

Постоялец

Знающий

Постоялец

Вложения

Постоялец

Знающий

Постоялец

Интересующийся

Постоялец

Постоялец

Знающий

Вложения

Постоялец

Похожие темы

Privacy & Transparency

Privacy & Transparency